home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
FM Towns: Free Software Collection 10
/
FM Towns Free Software Collection 10.iso
/
fb386
/
tool
/
watanabe
/
short
/
roreru.bas
< prev
next >
Wrap
BASIC Source File
|
1994-08-18
|
3KB
|
74 lines
1000 SCREEN 0:SCREEN@0
1010 CONSOLE 0,25,0:COLOR 7,0:CLS
1020 E_CR0=0:E_CR1=4:E_字数=3
1030 LOCATE 27,1
1040 PRINT"ローレル指数計算プログラム by 渡辺 良一"
1050 LOCATE 0,3
1060 PRINT"身長を入力してください。(cm)"
1070 E_文字$="":E_X=0:E_Y=4
1080 GOSUB *文字編集
1090 CM=VAL(E_文字$)
1100 PRINT"体重を入力してください。(kg)"
1110 E_文字$="":E_X=0:E_Y=6
1120 GOSUB *文字編集
1130 KG=VAL(E_文字$)
1140 R=CINT((KG/CM^3)*10000000)
1150 PRINT"ローレル指数=";R
1160 IF R<100 THEN
1170 PRINT"やせすぎ(99以下)"
1180 ELSE IF R<115 THEN
1190 PRINT"やせている(100~114)"
1200 ELSE IF R<145 THEN
1210 PRINT"標準(115~144)"
1220 ELSE IF R<160 THEN
1230 PRINT"ふとっている(145~159)"
1240 ELSE
1250 PRINT"ふとりすぎ(160以上)"
1260 ENDIF
1270 WHILE INKEY$="":WEND
1280 END
1290 '★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★
1300 *文字編集
1310 GOSUB *トラップ
1320 GOSUB *E_文字表示
1330 E_C=LEN(E_文字$)
1340 E_CR=E_CR1:GOSUB *E_書く
1350 LINE(E_X*8-1,E_Y*19-1)-STEP(E_字数*8+3,17),PSET,E_CR3,B
1360 *E_INKEY
1370 E_K$=INKEY$
1380 IF E_K$="" THEN *E_INKEY
1390 E_K=ASC(E_K$)
1400 IF E_K=13 THEN GOSUB *E_消す:RETURN
1410 IF E_K=5 AND E_C<LEN(E_文字$) THEN *E_一括削除
1420 IF E_K=8 AND E_C>0 THEN *E_後退
1430 IF E_K=127 THEN IF E_C<LEN(E_文字$) THEN *E_削除 ELSE *E_INKEY
1440 IF E_K=28 AND E_C<LEN(E_文字$) THEN E_I= 1:GOTO *E_移動
1450 IF E_K=29 AND E_C>0 THEN E_I=-1:GOTO *E_移動
1460 IF (E_K<&H30 OR &H39<E_K) AND (E_K<>&H2E OR INSTR(E_文字$,".")) THEN *E_INKEY
1470 IF LEN(E_文字$+E_K$)>E_字数 THEN GOSUB *トラップ:GOTO *E_INKEY
1480 E_文字$=LEFT$(E_文字$,E_C)+E_K$+MID$(E_文字$,E_C+1)
1490 E_I=1:GOSUB *E_文字表示:GOTO *E_移動
1500 *E_一括削除
1510 E_文字$=LEFT$(E_文字$,E_C)+STRING$(LEN(E_文字$)-E_C,32)
1520 GOSUB *E_文字表示
1530 E_文字$=LEFT$(E_文字$,E_C)
1540 GOTO *E_INKEY
1550 *E_後退
1560 E_文字$=LEFT$(E_文字$,E_C-1)+MID$(E_文字$,E_C+1)
1570 GOSUB *E_文字表示:E_I=-1:GOTO *E_移動
1580 *E_削除
1590 E_文字$=LEFT$(E_文字$,E_C)+MID$(E_文字$,E_C+2)
1600 GOSUB *E_文字表示
1610 GOTO *E_INKEY
1620 *E_移動
1630 GOSUB *E_消す
1640 E_C=E_C+E_I
1650 E_CR=E_CR1
1660 GOSUB *E_表示
1670 GOTO *E_INKEY
1680 *E_消す:E_CR=E_CR0:GOSUB *E_書く:RETURN
1690 *E_表示:E_CR=E_CR1:GOSUB *E_書く:RETURN
1700 *E_書く:LINE((E_X+E_C)*8,E_Y*19)-STEP(1,15),PSET,E_CR,B:RETURN
1710 *E_文字表示:LOCATE E_X,E_Y:PRINT E_文字$;" ":RETURN
1720 *トラップ:WHILE INKEY$<>"":WEND:RETURN